AccessTr.neT

Tam Versiyon: şifre giriş maskesi
Şu anda arşiv modunu görüntülemektesiniz. Tam versiyonu görüntülemek için buraya tıklayınız.
sayın üyeler
form, tablo vs. üzerinde şifre giriş maskesi password seçeneği ile yapılabiliyor
ancak ınputbox ile kontrol edilen bir formda girilen şifre görünüyor bununda *** şeklinde çıkması için bir yol var mıdır?
teşekkürler 
Bir modüle bu kodu ekle tamamdır.


'////////////////////////////////////////////////////////////////////

'Password masked inputbox
'Allows you to hide characters entered in a Vba Inputbox.
'
'Code written by Daniel Klann
'March 2003
'////////////////////////////////////////////////////////////////////
'API functions to be used

Private Declare Function CallNextHookEx Lib "user32" (ByVal hHook As Long, _
                                                      ByVal ncode As Long, ByVal wParam As Long, lParam As Any) As Long
 
Private Declare Function GetModuleHandle Lib "kernel32" Alias "GetModuleHandleA" (ByVal lpModuleName As String) As Long
 
Private Declare Function SetWindowsHookEx Lib "user32" Alias "SetWindowsHookExA" _
                                          (ByVal idHook As Long, ByVal lpfn As Long, ByVal hmod As Long, _
                                          ByVal dwThreadId As Long) As Long
 
Private Declare Function UnhookWindowsHookEx Lib "user32" (ByVal hHook As Long) As Long
 
Private Declare Function SendDlgItemMessage Lib "user32" Alias "SendDlgItemMessageA" _
                                            (ByVal hDlg As Long, ByVal nIDDlgItem As Long, ByVal wMsg As Long, _
                                            ByVal wParam As Long, ByVal lParam As Long) As Long
 
Private Declare Function GetClassName Lib "user32" Alias "GetClassNameA" (ByVal hwnd As Long, _
                                                                          ByVal lpClassName As String, _
                                                                          ByVal nMaxCount As Long) As Long
 
Private Declare Function GetCurrentThreadId Lib "kernel32" () As Long
 
'Constants to be used in our API functions
Private Const EM_SETPASSWORDCHAR = &HCC
Private Const WH_CBT = 5
Private Const HCBT_ACTIVATE = 5
Private Const HC_ACTION = 0
 
Private hHook As Long
 
Public Function NewProc(ByVal lngCode As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
    Dim RetVal
    Dim strClassName As String, lngBuffer As Long
 
    If lngCode < HC_ACTION Then
        NewProc = CallNextHookEx(hHook, lngCode, wParam, lParam)
        Exit Function
    End If
 
    strClassName = String$(256, " ")
    lngBuffer = 255
 
    If lngCode = HCBT_ACTIVATE Then    'A window has been activated
 
        RetVal = GetClassName(wParam, strClassName, lngBuffer)
 
        If Left$(strClassName, RetVal) = "#32770" Then  'Class name of the Inputbox
 
            'This changes the edit control so that it display the password character *.
            'You can change the Asc("*") as you please.
            SendDlgItemMessage wParam, &H1324, EM_SETPASSWORDCHAR, Asc("*"), &H0
        End If
 
    End If
 
    'This line will ensure that any other hooks that may be in place are
    'called correctly.
    CallNextHookEx hHook, lngCode, wParam, lParam
 
End Function
 
Public Function InputBoxDK(Prompt, Optional Title, Optional Default, Optional XPos, _
                        Optional YPos, Optional HelpFile, Optional Context) As String
 
    Dim lngModHwnd As Long, lngThreadID As Long
 
    lngThreadID = GetCurrentThreadId
    lngModHwnd = GetModuleHandle(vbNullString)
 
    hHook = SetWindowsHookEx(WH_CBT, AddressOf NewProc, lngModHwnd, lngThreadID)
 
    InputBoxDK = InputBox(Prompt, Title, Default, XPos, YPos, HelpFile, Context)
    UnhookWindowsHookEx hHook
 
End Function  'Hope someone can use it!
Merhaba. Küçük bir hatırlatma.

Eğer 64bit sistem kullanıyorsanız,

Alpeki99 kardeşimizin Vba Kodunda

"Declare Function" yazan yerleri "Declare Ptrsafe Function" olarak değiştiriniz.

Saygılar.
teşekkürler çok işimeyaradı
sayın karaayhan,

konu,Cevaplanmış Sorular kategorisi'ne taşındı.fakat,
sayın alpeki99'un paylaştıkları kodlara yönelik olarak,
(kendilerinin de iznine ve hoşgörüsüne sığınaraktan bir düzeltmede bulunmak istiyorum,naçizane.)

konunu 2.mesajında paylaşılan kod yarım kalmış bir kod.
devamında,asıl önemli olan ve uygulamada kullanılması gerekli son kod kısmının mevcut olmadığı görülmüştür.

ilgili kodun devamı (2.mesajda kaldığı yerden olacak şekilde) aşağıdaki gibi dahil edilmelidir.


Kod:
Public Function TEST()
Dim strAdminPWord As String
strAdminPWord = InputBoxDK("İşlem yapmanız için ŞİFRE girmelisiniz.", "ŞİFRE GİRİŞ UYARISI")

If strAdminPWord = "password" Then
    MsgBox "ŞİFRE doğru. ", vbOKOnly, "GEÇERLİ ŞİFRE GİRİŞİ"
    
Else
    MsgBox ("Hatalı ŞİFRE girdiniz!")
   ' Exit Sub
End If
End Function

kodun çalışması için de,
ilgili formunuzun YÜKLENDİĞİNDE olay yordamına ya da bir buton denetiminde kullanılacaksa TIKLANDIĞINDA olay yordamına,

Call TEST

ifadesini yazmak gerekmektedir.kod içerisindeki "password" ifadesin yer alan password yerine hangi şifreyi vermek istiyorsanız o ifade ile değiştiriniz.

EK'te;bahsi geçen bu hususlara yönelik olarak hazırlanmış örnek uygulama mevcuttur.


INPUT şifresi için 123 yazınız.inceleyebilirsiniz.

bilginize...iyi çalışmalar,saygılar.
süpersiniz sayın atoz112, "başarı ayrıntıda gizlidir"
tüm konu ve cevapları ayrıntılı ele almanız takdire şayan
emeğinize sağlık