AccessTr.neT
Body kısmında tablo mail atma - Baskı Önizleme

+- AccessTr.neT (https://accesstr.net)
+-- Forum: Microsoft Access (https://accesstr.net/forum-microsoft-access.html)
+--- Forum: Access Cevaplanmış Soruları (https://accesstr.net/forum-access-cevaplanmis-sorulari.html)
+--- Konu Başlığı: Body kısmında tablo mail atma (/konu-body-kisminda-tablo-mail-atma.html)

Sayfalar: 1 2


Body kısmında tablo mail atma - kadirdursun - 23/04/2016

Arkadaşlar merhaba; 

Öncelikle 23 Nisan Ulusal Egemenlik ve Çocuk Bayramınız kutlu olsun.

Ekteki örnekte bulunan F_SIKAYET formunda YENİ ŞİKAYETİ MAİL AT ve AKTİF ŞİKAYETLERİ MAİL AT adında iki butonum var. 

Bu butonlara tıklayınca mail bilgisindeki gruba mail atmasını istiyorum. (Bu grubu outlook’tan oluşturdum.) 

Mail atma ile ilgili sitemizden bulduğum örnekleri inceleyerek her iki buton içinde bir kod uyarladım. 

İstediğim atılan maillerin body kısmına Excel tablosu şeklinde sütunlu olarak eklenmesi. Hatta sondada boş bir sütun kalması. (Bu son sütunu mail attığım kişi doldurup bana mailleyecek.) 

Her iki buton içinde bu tip bir Excel tablosunu ek olarak değilde mailin gövdesinde nasıl gönderebiliriz?


Cvp: Body kısmında tablo mail atma - ozanakkaya - 23/04/2016

https://accesstr.net/konu-maili-tablo-halinde-gonderme.html Bağlantısındaki konuyu inceleyiniz.


Cvp: Body kısmında tablo mail atma - kadirdursun - 25/04/2016

Bu örneği inceledim ve 1. mesaja uyarlamıştım.
Bu haliyle işimi pek görmedi.
Mail gövdesine tablo şeklinde eklenmesini istiyorum.


Cvp: Body kısmında tablo mail atma - ozanakkaya - 26/04/2016

(25/04/2016, 12:41)kadirdursun yazdı: Bu örneği inceledim ve 1. mesaja uyarlamıştım.
Bu haliyle işimi pek görmedi.
Mail gövdesine tablo şeklinde eklenmesini istiyorum.

Kadir bey,  1. mesajdaki örnek uygulamanızda 
.Body = "TARİH: " & Me.TARIH & "" _
& Chr(10) & Chr(10) & "Başvuru No: " & Me.BASVURU_NO & "" _
& Chr(10) & "__________________________________________________________________________________________________________________________________________________" & "" _
& Chr(10) & Chr(10) & "Durum : " & Me.DURUM & "" _
& Chr(10) & "__________________________________________________________________________________________________________________________________________________" & "" _
& Chr(10) & Chr(10) & "İlçe: " & Me.ILCE & "" _
& Chr(10) & "__________________________________________________________________________________________________________________________________________________" & "" _
& Chr(10) & Chr(10) & "Adı Soyadı: " & Me.ADI_SOYADI & "" _
& Chr(10) & "__________________________________________________________________________________________________________________________________________________" & "" _
& Chr(10) & Chr(10) & "Telefon: " & Me.TELEFON & "" _
& Chr(10) & "__________________________________________________________________________________________________________________________________________________" & "" _
& Chr(10) & Chr(10) & "Adres: " & Me.ADRES & "" _
& Chr(10) & "__________________________________________________________________________________________________________________________________________________" & "" _
& Chr(10) & Chr(10) & "Şikayet: " & Me.SIKAYET & "" _
& Chr(10) & "__________________________________________________________________________________________________________________________________________________" & "" _
& Chr(10) & Chr(10) & " Cevap Tarihi: " & Me.CEVAP_TARIHI & "" _
& Chr(10) & Chr(10) & " Cevap : " & Me.CEVAP & "" _
& Chr(10) & Chr(10) & "LÜTFEN EN KISA ZAMANDA CEVAPLAYINIZ"
şeklinde kodlama bulunmaktadır.
Ancak, benim bağlantısını verdiğim uygulamadaki çözümde ilgili kodlama aşağıdaki gibi,
mtn_body = mtn_body & "<table><tbody><tr><td style='width:100px;'>Kalite:</td><td style='width:100px;'>En:</td><td style='width:100px;'>Metraj:</td></tr><tr>"

For a = 0 To Trim(Forms!fiyatsorgu!fiyat_dalt.Form.RecordsetClone.RecordCount) - 1
mtn_body = mtn_body & "<td>" & [fiyat_dalt].Form![d_kalite] & "</td>"
mtn_body = mtn_body & "<td>" & [fiyat_dalt].Form![d_metraj] & "</td>"
mtn_body = mtn_body & "<td>" & [fiyat_dalt].Form![d_en] & "</td>"
mtn_body = mtn_body & "<tr></tr>"
Me.fiyat_dalt.SetFocus
DoCmd.GoToRecord , , acNext
Next a
mtn_body = mtn_body & "</tr></tbody></table>"
mtn_body = mtn_body
Yani body kısmına Html tablo tagları ekliyor.


Cvp: Body kısmında tablo mail atma - kadirdursun - 27/04/2016

Yukarıdaki kodları örneğime uyguladım.
Outlook sayfasını açıyor fakat bilgileri eklemiyor.

(Ekteki örnekte bulunan F_SIKAYET formunda Gönder sekmesindeki MAİL GÖNDER butonu)


Cvp: Body kısmında tablo mail atma - ozanakkaya - 28/04/2016

Merhaba,

Butonun tıklandığında olayındaki kodları aşağıdaki ile değiştiriniz.

    Dim olApp As Object
    Dim olItem As Variant
    Dim db As DAO.Database
    Dim Kayit As DAO.Recordset
    Dim Sorgum As String
    Dim Baslik(1 To 7) As String
    Dim Satir(1 To 7) As String
    Dim Govde() As String
    Dim SatirSayisi As Long

    Baslik(1) = "Tarih"
    Baslik(2) = "Başvuru No"
    Baslik(3) = "Durum"
    Baslik(4) = "İlçe"
    Baslik(5) = "Adres"
    Baslik(6) = "Adı Soyadı"
    Baslik(7) = "Telefon"

    SatirSayisi = 1
    ReDim Govde(1 To SatirSayisi)
    Govde(SatirSayisi) = "<HTML><body><table border='2'><tr><th>" & Join(Baslik, "</th><th>") & "</th></tr>"

    Sorgum = "SELECT * From Sorgu1"
    Set db = CurrentDb
    Set Kayit = CurrentDb.OpenRecordset(Sorgum)

    If Not (Kayit.BOF And Kayit.EOF) Then
        Do While Not Kayit.EOF
            SatirSayisi = SatirSayisi + 1
            ReDim Preserve Govde(1 To SatirSayisi)
            Satir(1) = Kayit("TARIH")
            Satir(2) = Kayit("BASVURU_NO")
            Satir(3) = Kayit("DURUM")
            Satir(4) = Kayit("ILCE")
            Satir(5) = Kayit("ADRES")
            Satir(6) = Kayit("ADI_SOYADI")
            Satir(7) = Kayit("TELEFON")
            Govde(SatirSayisi) = "<tr><td>" & Join(Satir, "</td><td>") & "</td></tr>"
            Kayit.MoveNext
        Loop
    End If

    Govde(SatirSayisi) = Govde(SatirSayisi) & "</table></body></html>"

    Set olApp = CreateObject("Outlook.application")
    Set olItem = olApp.CreateItem(0)

    olItem.Display
    olItem.To = Me.BOLGE
    olItem.Subject = Me.BOLGE & " 'YE AİT " & Me.BASVURU_NO & " NOLU ŞİKAYET BAŞVURUSU"
    olItem.HTMLBody = Join(Govde, vbNewLine)
    olItem.Display