Sayın Hocalarım,değerli form üyeleri,

Ekteki çalışmamda Odeme_bilgileri formunda bulunan Odeme_tutarı alanının Günclleştirme Sonrası olayında iki farklı işlemi yapmam gerekiyor birisi altforma kayıt yapıyor,diğeri veriyi kasaya gönderiyor altforma kayıt yapma olayını uyguladım,ama kasaya gönderme işlemini gerçekleştiremiyorum böyle bir durumda her iki uygulama kodlarını birleştirmekmi gerekiyor yoksa başka bir çözüm yolumu var bilemediğim için takıldım kaldım.Bu konuda öneri veya mümkünse yardımlarınıza ihtiyacım var.
Zira her iki kod grubunun başvuru adresi aynı..


Saygılarımla.
İyi çalışmalar

frm_odemebilgileri formundaki odeme_tutari metin kutusunun güncelleştirme sonrasında olayındaki kodu aşağıdaki ile değiştir.

Dim db As Database



Dim rs, rs2, rs3 As DAO.Recordset

Dim strSQL, strSQL2, strSQL3 As String

Set db = CurrentDb()

strSQL = "SELECT  * FROM tbl_odeme_bilgileri"

strSQL2 = "SELECT  * FROM tbl_KASA"

strSQL3 = "SELECT TOP 1 ISLEMTARIHI AS tarihkontrol, tbl_KASA.* FROM tbl_KASA WHERE (((ISLEMTARIHI)=Date()) AND (([GELIRCESIDI]) Is Null));"



Set rs = db.OpenRecordset(strSQL)

rs.AddNew

rs!Odano = Me.Parent.Odano

rs!odeme_Tarihi = Now()

rs!odeme_yontemi = Me.odeme_yontemi

rs!odeme_tutari = Me.odeme_tutari

rs.Update



Set rs2 = db.OpenRecordset(strSQL2)

Set rs3 = db.OpenRecordset(strSQL3)



    If rs3.EOF Then

        rs2.AddNew

        rs2!ISLEMTARIHI = Me.odeme_Tarihi

        rs2!GELIRCESIDI = "KONAKLAMA"

            If Me.odeme_yontemi = "Nakit" Then

                rs2!NAKIT = Me.odeme_tutari

            ElseIf Me.odeme_yontemi = "Kredi Kartı" Then

               rs2!KREDIKARTI = Me.odeme_tutari

            ElseIf Me.odeme_yontemi = "Banka" Then

               rs2!BANKA = Me.odeme_tutari

            End If

        rs2.Update

    Else

        rs3.Edit

        rs3!GELIRCESIDI = "KONAKLAMA"

            If Me.odeme_yontemi = "Nakit" Then

              rs3!NAKIT = Me.odeme_tutari

            ElseIf Me.odeme_yontemi = "Kredi Kartı" Then

              rs3!KREDIKARTI = Me.odeme_tutari

            ElseIf Me.odeme_yontemi = "Banka" Then

              rs3!BANKA = Me.odeme_tutari

            End If

        rs3.Update

    End If

    

rs.Close

rs2.Close

rs3.Close

db.Close



Set rs = Nothing

Set rs2 = Nothing

Set rs3 = Nothing

Set db = Nothing



Me.odeme_Tarihi = Null

Me.odeme_yontemi = Null

Me.odeme_tutari = Null

Me.Recalc

Me.odeme_Tarihi.SetFocus

Me.Parent.frm_odeme_bilgileri1.Requery

Sayın Ozan Hocam,
Yine muhteşemsiniz sağolun varolun emeğinize aklınıza sağlık,Allah razı olsun.
Konu çözülmüştür.
Saygılarımla..