Skip to main content

AccessTr.neT

Kayıt Ol

 | Facebook ile Bağlan  | Twitter İle Bağlan | Google+ İle Bağlan

Ünvana Göre Mail Gönderimi

bonasera
bonasera
Access Cevaplanmış Soruları
16
5999

Ünvana Göre Mail Gönderimi

Çözüldü #1
bonasera
Aktif Üye
bonasera
Bul
Aktif Üye
Adı Soyadı: Er.... Şı....
Konum: Edirne
Ofis Versiyonu: Ofis 2013 64 Bit
Son Oturumu: 10/05/2022,12:12
Yorumları: 97
Konuları: 10
Kayıt Tarihi: 29/10/2008
Teşekkür Puanı: 0
Değerli Arkadaşlar Merhaba,

Ben bir personel formu yaptım. Bu formda bilgilerin olduğu formda e-maile bastığımda o kişiye mail gönderebiliyorum. Ancak benim istediğim, ünvana göre mail göndermek, Yani bir comboboxtan ünvanı seçip ünvanı seçili olan kişilere mail göndermek. Bir de tüm kişilere mail göndermek.

Her zamanki gibi forumda araştırma yaptım ancak, baktığım konular toplu mail gönderme ile ilgili.

Lütfen yardımcı olur musunuz? Sadd

personelformu.rar
Cevapla
Çözüldü #2
Seruz
Uzman
Seruz
www Bul
Uzman
Adı Soyadı: Se.... UZ....
Yaşı: 53
Konum: Tekirdağ
Ofis Versiyonu: Ofis 2016 64 Bit
Son Oturumu: 17/12/2024,11:40
Yorumları: 1.579
Konuları: 8
Kayıt Tarihi: 30/10/2008
Teşekkür Puanı: 825
Mesleğiniz: BT Şefi
Sn. bonasera,

Yorumunuzda seçili kişiye mail gönderebiliyorum yazmışsınız ama gönderdiğiniz örnekteki formda E-Posta komut düğmesinde herhangi bir kod görünmüyor.

Ayrıca bahsettiğiniz gibi Ünvan seçme içeren bir formda yok.

Benim daha önce DAO ile sorgudaki kayıtları teker teker okuyup sırayla mail gönderdiğim bir kod vardı, onu gönderiyorum


Private Sub Ilgililere_Mail_Gonder()

On Error GoTo Hata

'---------------------------------------------------------------

    Dim DB As DAO.Database, RS As DAO.Recordset

    Dim objMessage As Object

    Dim SMTP_Sunucu, strBody

    Dim Kullanicinin_Adi, Kullanicinin_Mail_Adresi, Kullanicinin_Mail_Sifresi

    Dim TalepEdenin_Adi, TalepEdenin_Mail_Adresi

    Dim Onceki_TALEP_EDEN

    Const cdoAnonymous = 0

    Const cdoBasic = 1

    Const cdoNTLM = 2

    '---------------------------------------------------------------

    SMTP_Sunucu = "smtp.bline.net.tr"

    Kullanicinin_Adi = Me.TALEP_EDEN.Column(1)

    Kullanicinin_Mail_Adresi = Me.TALEP_EDEN.Column(2)

    Kullanicinin_Mail_Sifresi = Me.TALEP_EDEN.Column(3)

    If Kullanicinin_Mail_Adresi = "" Or Kullanicinin_Mail_Sifresi = "" Then

        MsgBox "Gerekli bilgileriniz eksik olduğu için Malzeme Talep Edenlere e-posta gönderilemiyor !" & vbCrLf & "Lütfen Bilgi Teknolojileri Departmanına bilgi veriniz", vbCritical, "Hata oluştu."

        Exit Sub

    End If

    '---------------------------------------------------------------

    Set DB = CurrentDb()

    Set RS = DB.OpenRecordset("Select * From Malzeme_Alis_MailListesi Where HRB_ID=" & [Forms]![Malzeme_Alis]![IrsListesi], dbOpenForwardOnly)

    Set objMessage = CreateObject("CDO.Message")

    Onceki_TALEP_EDEN = ""

    Do While Not RS.EOF

        '---------------------------------------------------------------

        If Onceki_TALEP_EDEN <> RS.Fields("TALEP_EDEN") Then

            '---------------------------------------

            'Bir önceki kişiye mail gönderiliyor

            '---------------------------------------

            If Onceki_TALEP_EDEN <> "" Then

                strBody = strBody & "</table>"

                strBody = strBody & "</font><br><br>"

                '---------------------------------------------------------------

                objMessage.Subject = "Gelen Malzeme Bilgisi"

                objMessage.From = Kullanicinin_Adi & "<" & Kullanicinin_Mail_Adresi & ">"

                objMessage.To = TalepEdenin_Mail_Adresi

                objMessage.HTMLBody = strBody

                objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusername") = Kullanicinin_Mail_Adresi

                objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendpassword") = Kullanicinin_Mail_Sifresi

                objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2

                objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = SMTP_Sunucu

                objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = cdoBasic

                objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 587

                objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = False

                objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 60

                objMessage.Configuration.Fields.Update

                objMessage.Send

                '---------------------------------------------------------------

            End If

            TalepEdenin_Adi = RS.Fields("Kull_ADI")

            TalepEdenin_Mail_Adresi = RS.Fields("Kull_MAIL")

            '---------------------------------------

            ' Yeni kişi için yeni mail oluşturuluyor

            '---------------------------------------

            strBody = ""

            strBody = strBody & "<p>"

            strBody = strBody & "<font face='Verdana' size='2'>"

            strBody = strBody & "Sn. " & TalepEdenin_Adi

            strBody = strBody & "<br><br>"

            strBody = strBody & "Talep etmiş olduğunuz malzeme(ler) gelmiştir."

            strBody = strBody & "<br><br>"

            strBody = strBody & "'MALZEME TALEPLERİ' programında açılış formunda veya "

            strBody = strBody & "<br>"

            strBody = strBody & " menüden 'Teslim Onayı' formunu seçerek gelen malzemeleri "

            strBody = strBody & "<br>"

            strBody = strBody & " teslim aldığınızı onaylamalısınız."

            strBody = strBody & "<br>"

            strBody = strBody & "Teslim onayından sonra malzemelerinizi depodan alabilirsiniz."

            strBody = strBody & "<br><br><br>"

            strBody = strBody & "Gelen Malzemeler:"

            strBody = strBody & "</font>"

            strBody = strBody & "</p>"

            strBody = strBody & "<table border='1' cellspacing='0' cellpadding='1' font face='Verdana' size='1' bgcolor='LightBlue'>"

            strBody = strBody & "<tr>"

            strBody = strBody & "<td><b>&nbsp;Talep Tarihi&nbsp;</b></td>"

            strBody = strBody & "<td><b>&nbsp;Talep No&nbsp;</b></td>"

            strBody = strBody & "<td><b>&nbsp;Malzeme&nbsp;</b></td>"

            strBody = strBody & "<td><b>&nbsp;Miktar&nbsp;</b></td>"

            strBody = strBody & "</tr>"

            '------

            Onceki_TALEP_EDEN = RS.Fields("TALEP_EDEN")

        End If

        '---------------------------------------------------------------

        strBody = strBody & "<tr>"

        strBody = strBody & "<td>&nbsp;" & RS.Fields("TALEP_TARIHI") & "&nbsp;</td>"

        strBody = strBody & "<td>&nbsp;" & RS.Fields("TALEP_NO") & "&nbsp;</td>"

        If IsNull(RS.Fields("MLZ_OZELLIK")) Then

            strBody = strBody & "<td>&nbsp;" & RS.Fields("MLZ_TANIMI") & "&nbsp;</td>"

        Else

            strBody = strBody & "<td>&nbsp;" & RS.Fields("MLZ_TANIMI") & "(" & RS.Fields("MLZ_OZELLIK") & ")&nbsp;</td>"

        End If

        strBody = strBody & "<td align=right>&nbsp;" & RS.Fields("MLZ_MIKTARI") & " " & RS.Fields("MLZ_BIRIMI") & "&nbsp;</td>"

        strBody = strBody & "</tr>"

        RS.MoveNext

    Loop

    RS.Close

    Set RS = Nothing

    

    '---------------------------------------

    'Son kişiye mail gönderiliyor

    '---------------------------------------

    If Onceki_TALEP_EDEN <> "" Then

        strBody = strBody & "</table>"

        strBody = strBody & "</font><br><br>"

        '---------------------------------------------------------------

        objMessage.Subject = "Gelen Malzeme Bilgisi"

        objMessage.From = Kullanicinin_Adi & "<" & Kullanicinin_Mail_Adresi & ">"

        objMessage.To = TalepEdenin_Mail_Adresi

        objMessage.HTMLBody = strBody

        objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusername") = Kullanicinin_Mail_Adresi

        objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendpassword") = Kullanicinin_Mail_Sifresi

        objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2

        objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = SMTP_Sunucu

        objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = cdoBasic

        objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 587

        objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = False

        objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 60

        objMessage.Configuration.Fields.Update

        objMessage.Send

        '---------------------------------------------------------------

    End If

    

    MsgBox "İlgili kişi(lere) e-posta gönderilmiştir.", vbInformation, "İşlem tamam"

Exit Sub

'---------------------------------------------------------------

Hata:

    MsgBox "Talep edene e-posta gönderimi başarısız oldu!", vbCritical, "Hata oluştu."

End Sub
Bu kodda aynı kişinin birden fazla olabilmesi durumunda bir kez gönderebilmesi için bazı kontroller var (Onceki_TALEP_EDEN),
onları kaldırmanız lazım. O zaman DAO kullanmışım, isterseniz ADO'ya çevirin, daha iyi ve hızlı olur.

Ayrıca, bu kodun gönderdiği mailin örnek formatını ve benzer programını aşağıdaki konunun 3. ve 5. sayfalarında bulabilirsiniz.
formdaki bilgileri ilgili kişiye eposta olarak gönderme

Örneğimde kullandığım metodu sn. ozanakkaya'nın aşağıdaki örneğinden alınmıştır.
SMTP Hesabıyla E-mail Gönderme Uygulaması
Bildiğini bilenin arkasından git, bildiğini bilmeyeni uyar, bilmediğini bilene öğret, bilmediğini bilmeyenden kaç.
Konfüçyüs
Cevapla
Çözüldü #3
bonasera
Aktif Üye
bonasera
Bul
Aktif Üye
Adı Soyadı: Er.... Şı....
Konum: Edirne
Ofis Versiyonu: Ofis 2013 64 Bit
Son Oturumu: 10/05/2022,12:12
Yorumları: 97
Konuları: 10
Kayıt Tarihi: 29/10/2008
Teşekkür Puanı: 0
Teşekkürler Sayın Seruz. E-posta butonunun tıklandığında olayında katıştırılmış bir makro var. O makro sayesinde gönderiliyor. Tekrar incelemeniz mümkün mü acaba? Bir de ben kod yerleştiremiyorum pek formlarıma.. Çoğu zaman çalışmıyor.
Cevapla
Çözüldü #4
Seruz
Uzman
Seruz
www Bul
Uzman
Adı Soyadı: Se.... UZ....
Yaşı: 53
Konum: Tekirdağ
Ofis Versiyonu: Ofis 2016 64 Bit
Son Oturumu: 17/12/2024,11:40
Yorumları: 1.579
Konuları: 8
Kayıt Tarihi: 30/10/2008
Teşekkür Puanı: 825
Mesleğiniz: BT Şefi
Pardon, makroyu farketmemişim. Bu gün hiç vaktim olmadı maalesef.
Yarında fırsat bulabilirsem ancak akşamüstü bakabilirim, tabii ki oruçtan halim kalırsa.
Bildiğini bilenin arkasından git, bildiğini bilmeyeni uyar, bilmediğini bilene öğret, bilmediğini bilmeyenden kaç.
Konfüçyüs
Cevapla
Çözüldü #5
bonasera
Aktif Üye
bonasera
Bul
Aktif Üye
Adı Soyadı: Er.... Şı....
Konum: Edirne
Ofis Versiyonu: Ofis 2013 64 Bit
Son Oturumu: 10/05/2022,12:12
Yorumları: 97
Konuları: 10
Kayıt Tarihi: 29/10/2008
Teşekkür Puanı: 0
Teşekkürler Sayın Seruz. İnşallah ilgilenebilirsiniz..
Cevapla
Çözüldü #6
Seruz
Uzman
Seruz
www Bul
Uzman
Adı Soyadı: Se.... UZ....
Yaşı: 53
Konum: Tekirdağ
Ofis Versiyonu: Ofis 2016 64 Bit
Son Oturumu: 17/12/2024,11:40
Yorumları: 1.579
Konuları: 8
Kayıt Tarihi: 30/10/2008
Teşekkür Puanı: 825
Mesleğiniz: BT Şefi
Öncelikle kodun içerisinde, gönderecek mail adresine ait bilgilerin doldurulması gerekiyor.
Daha kolay olması için, unvan seçip mail gönderme işini ayrı bir formda yaptım.
Bir deneyin bakalım, sizde problemsiz çalışacak mı?

Private Sub btn_EPOSTA_Click()

On Error GoTo Hata

'---------------------------------------------------------------

 Dim DB As DAO.Database, RS As DAO.Recordset

 Dim objMessage As Object

 Dim SMTP_Sunucu, strBody

 Dim Kullanicinin_Adi, Kullanicinin_Mail_Adresi, Kullanicinin_Mail_Sifresi

 Dim TalepEdenin_Adi, TalepEdenin_Mail_Adresi

 Const cdoAnonymous = 0

 Const cdoBasic = 1

 Const cdoNTLM = 2

 '---------------------------------------------------------------

 ' Buraya kendi mail bilgilerinizi girmeniz gerekiyor.

 ' İsterseniz bir tablodan veya formdan sorarak alabilirsiniz

 '---------------------------------------------------------------

 SMTP_Sunucu = "smtp.bline.net.tr"

 Kullanicinin_Adi = "Adı ve Soyadı"

 Kullanicinin_Mail_Adresi = "mail adresiniz"

 Kullanicinin_Mail_Sifresi = "Mail şifreniz"

 '---------------------------------------------------------------

 Set DB = CurrentDb()

 'Set RS = DB.OpenRecordset(Me.Personel_Listesi.RowSource, dbOpenForwardOnly)

 Set RS = DB.OpenRecordset("Select * From Personel Where unvan Like '" & Forms![E-Posta]!Secilen_Unvan & "*'", dbOpenForwardOnly)

 Set objMessage = CreateObject("CDO.Message")

 Do While Not RS.EOF

 '---------------------------------------------------------------

 ' Okunan kayıttaki kişi için mail bilgileri oluşturuluyor ve gönderiliyor

 '---------------------------------------------------------------

 strBody = "Sn. " & RS.Fields("adi") & " " & RS.Fields("soyadi")

 strBody = strBody & " gönderilecek metni buraya yazın"

 '---------

 objMessage.Subject = "Deneme Maili"

 objMessage.From = Kullanicinin_Adi & "<" & Kullanicinin_Mail_Adresi & ">"

 objMessage.To = RS.Fields("email")

 objMessage.HTMLBody = strBody

 objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusername") = Kullanicinin_Mail_Adresi

 objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendpassword") = Kullanicinin_Mail_Sifresi

 objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2

 objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = SMTP_Sunucu

 objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpauthenticate") = cdoBasic

 objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = 587

 objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpusessl") = False

 objMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpconnectiontimeout") = 60

 objMessage.Configuration.Fields.Update

 objMessage.Send

 '---------------------------------------------------------------

 RS.MoveNext

 Loop

 RS.Close

 Set RS = Nothing

 MsgBox "İlgili kişi(lere) e-posta gönderilmiştir.", vbInformation, "İşlem tamam"



Exit Sub

'---------------------------------------------------------------

Hata:

 MsgBox "E-posta gönderimi başarısız oldu!", vbCritical, "Hata oluştu."

 MsgBox Err.Number & ":" & Err.Description

End Sub
.rar PersonelFormu_Seruz.rar (Dosya Boyutu: 2,52 MB | İndirme Sayısı: 59)
Bildiğini bilenin arkasından git, bildiğini bilmeyeni uyar, bilmediğini bilene öğret, bilmediğini bilmeyenden kaç.
Konfüçyüs
Cevapla

Bir hesap oluşturun veya yorum yapmak için giriş yapın

Yorum yapmak için üye olmanız gerekiyor

ya da
Task