ListObjects Tables_Linked
Yukardaki gibi çağırılırsa bağlantılı tablo adları bulunur anladığım koddan.

Adam enum ile ayarlamış ve ordaki yazlılanlara göre tablo adı,form adı gibi olanlar bulunur anladığım.

Aklımdayken sorayım hani olmazda tablo adının başına MSys ile başlatırsak o tabloyuda teyet geçer heralde.

Tablo oluştururken MSys ile başlasak sorun olurmu yani system olarak algılarmı.

Enum ObjectType
    Tables_Local = 1
    Tables_Linked_ODBC = 4
    Tables_Linked = 6
    Queries = 5
    Forms = -32768
    Reports = -32764
    Macros = -32766
    Modules = -32761
End Enum
 
Function ListObjects(lObjectType As ObjectType)
    On Error GoTo Error_Handler
    Dim db                    As DAO.Database
    Dim rs                    As DAO.Recordset
    Dim sSQL                  As String
 
    sSQL = "SELECT MsysObjects.Name AS [ObjectName]" & vbCrLf & _
          " FROM MsysObjects" & vbCrLf & _
          " WHERE (((MsysObjects.Name Not Like '~*') And (MsysObjects.Name Not Like 'MSys*'))" & vbCrLf & _
          "    AND (MsysObjects.Type=" & lObjectType & "))" & vbCrLf & _
          " ORDER BY MsysObjects.Name;"
 
    Set db = CurrentDb
    Set rs = db.OpenRecordset(sSQL, dbOpenSnapshot)
    With rs
        If .RecordCount <> 0 Then
            Do While Not .EOF
                Debug.Print ![ObjectName]
                .MoveNext
            Loop
        End If
    End With
 
Error_Handler_Exit:
    On Error Resume Next
    If Not rs Is Nothing Then
        rs.Close
        Set rs = Nothing
    End If
    If Not db Is Nothing Then Set db = Nothing
    Exit Function
 
Error_Handler:
    MsgBox "The following error has occurred" & vbCrLf & vbCrLf & _
          "Error Number: " & Err.Number & vbCrLf & _
          "Error Source: ListObjects" & vbCrLf & _
          "Error Description: " & Err.Description & _
          Switch(Erl = 0, "", Erl <> 0, vbCrLf & "Line No: " & Erl) _
          , vbOKOnly + vbCritical, "An Error has Occurred!"
    Resume Error_Handler_Exit
End Function